Lernpfad:Objektorientierte Programmierung mit Processing/4

Vorheriger Schritt

Nächster Schritt

Die Sonne scheint. Nun wird es Zeit, die Erde zu "erschaffen".

Wir erstellen eine neue Klasse Planet, mit der wir später auch weitere Planeten anlegen können. Welche Eigenschaften braucht ein Planet? Seine Position ist abhängig von dem Stern (der Sonne), um die er kreist. Daher legen wir eine Entfernung und eine Geschwindigkeit für den Planeten fest, mit der er um die Sonne kreist. Außerdem kennt er das Sun-Objekt, das in seinem Rotationszentrum liegt.

Arbeitsauftrag

1. Erstelle einen neuen Tab "Planet".
2. Erstelle im neuen Tab eine Klasse Planet mit den Eigenschaften String name, float distance, float angle, float speed, float x und float y.
3. Erstelle einen Konstruktor für die Klasse, der als Parameter den Namen, die Sonne, die Entfernung und die Geschwindigkeit übergeben bekommt. Die Eigenschaften angle, x und y werden zunächst auf 0.0 gesetzt.

Lösung zu 2

class Planet {

  private String name;

  private float x;
  
  private float y;
  
  private float distance;
  
  private float angle;

  private float speed;

  private Sun sun;

}

Lösung zu 3

class Planet {

  private String name;

  private float x;
  
  private float y;
  
  private float distance;
  
  private float angle;

  private float speed;

  private Sun sun;

  public Planet( String pName, Sun pSun, float pDist, float pSpeed ) {
    name = pName;
    sun = pSun;
    distance = pDist;
    
    speed = pSpeed;
    angle = 0.0;
    x = 0.0;
    y = 0.0;
  }

}

Die Position des Planeten wird relativ zur Sonne bestimmt. (Unsere Sonne ist bei [math]\displaystyle{ (0|0) }[/math], aber ggf. gibt es andere Sonnen, die andere Koordinaten haben.) Die berechnete Position aus Entfernung und Rotationswinkel muss daher um die Position der Sonne verschoben werden (auf die du z.B. mit sun.getX() zugreifen kannst).

Arbeitsauftrag

1. Implementiere Getter für x und y, die die absolute Position (relativ zur Sonne) des Planeten berechnen und zurückgeben.
2. Implementiere nun (analog zu Sun) eine draw-Methode, die unseren (blauen) Planeten an seine absoluten Koordinaten zeichnet. (Tipp: In der Referenz zum fill-Befehl wird erklärt, wie du Farben nutzen kannst.)

Lösung zu 1

  public float getX() {
    return sun.getX()+x;
  }

  public float getY() {
    return sun.getY()+y;
  }

Lösung zu 2

  public void draw() {
    noStroke();
    fill(0,0,255);
    ellipse(getX(),getY(),20,20);
  }

Jetzt müssen wir nur noch das Hauptprogramm so modifizieren, dass der Planet angezeigt wird:

Sun sun = new Sun();
Planet earth = new Planet("Earth", sun, 120.0, -.01);

void setup() {
  size(800, 600);
}

void draw() {
  // width und height sind die Breite / Höhe des Programmfensters.
  // Du könntest hier auch einfach 400 und 300 benutzen.
  translate(width/2, height/2);
  background(0);
  
  sun.draw();
  earth.draw();
}

Oh nein! Unser schöner Planet ist in der Sonne verglüht. Wir sollten schnell die Position der Erde anpassen, damit das nicht wieder passiert.